-- Copyright (C)2026, Philip Munts dba Munts Technologies.
--
-- Redistribution and use in source and binary forms, with or without
-- modification, are permitted provided that the following conditions are met:
--
-- * Redistributions of source code must retain the above copyright notice,
--   this list of conditions and the following disclaimer.
--
-- THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS IS"
-- AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
-- IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
-- ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT HOLDER OR CONTRIBUTORS BE
-- LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR
-- CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF
-- SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS
-- INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN
-- CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE)
-- ARISING IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
-- POSSIBILITY OF SUCH DAMAGE.

WITH Ada.Environment_Variables;
WITH Ada.Text_IO; USE Ada.Text_IO;
WITH System;
WITH System.Address_To_Access_Conversions;

USE TYPE System.Address;

PACKAGE BODY MQTT.Paho IS

  PACKAGE env RENAMES Ada.Environment_Variables;

  PACKAGE SCC IS NEW System.Address_To_Access_Conversions(Server_Class);

  -- Get a configuration value, from an argument or from an environment variable

  FUNCTION GetEnv(arg : String; var : String; default : String) RETURN String IS

  BEGIN
    RETURN (IF arg /= default THEN arg ELSE env.Value(var, default));
  END GetEnv;

  -- Initialize an MQTT server object instance

  PROCEDURE Initialize
   (Self      : IN OUT Server_Class;
    URI       : String       := Default_URI;
    ID        : String       := Default_ID;
    callback3 : SubCallback3 := Null) IS

    error : Integer;

  BEGIN
    Self.Destroy;

    Create(Self.handle,
      GetEnv(URI, "MQTT_URI", Default_URI) & ASCII.Nul,
      GetEnv(ID,  "MQTT_ID", Default_ID)   & ASCII.Nul,
      SCC.To_Address(Self'Unchecked_Access), error);

    IF error /= 0 THEN
      Self.Destroy;
      RAISE MQTT.Error WITH "Paho_MQTT_sync.Create() failed, " &
        strerror(error);
    END IF;

    Self.callback3 := callback3;
  END Initialize;

  -- Destroy an MQTT server object instance

  PROCEDURE Destroy(Self : IN OUT Server_Class) IS

    error : Integer;

  BEGIN
    IF Self = Destroyed THEN
      RETURN;
    END IF;

    IF Self.connected THEN
      Self.Disconnect(Default_Timeout);
      Self.connected := false;
    END IF;

    Destroy(Self.handle, error);

    IF error /= 0 THEN
      RAISE MQTT.Error WITH "Paho_MQTT_sync.Destroy() failed, " &
        strerror(error);
    END IF;

    Self := Destroyed;
  END Destroy;

  -- Connect to the server

  PROCEDURE Connect
   (Self      : Server_Class;
    username  : String := Default_User;
    password  : String := Default_Pass) IS

    error : integer;

  BEGIN
    Self.CheckDestroyed;

    Connect(Self.handle,
      GetEnv(username, "MQTT_USER", Default_User) & ASCII.Nul,
      GetEnv(password, "MQTT_PASS", Default_Pass) & ASCII.Nul, error);

    IF error /= 0 THEN
      RAISE MQTT.Error WITH "Paho_MQTT_sync.Connect() failed, "
        & strerror(error);
    END IF;
  END Connect;

  -- Disconnect from the server

  PROCEDURE Disconnect
   (Self      : Server_Class;
    timeoutms : Natural := Default_Timeout) IS

    error : Integer;

  BEGIN
    Self.CheckDestroyed;

    Disconnect(Self.handle, timeoutms, error);

    IF error /= 0 THEN
      RAISE MQTT.Error WITH "Paho_MQTT_sync.Disconnect() failed, " &
        strerror(error);
    END IF;
  END Disconnect;

  -- Publish a string message to the server

  PROCEDURE Publish
   (Self      : Server_Class;
    topic     : String;
    message   : String;
    QOS       : Integer := Default_QOS) IS

    error : Integer;

  BEGIN
    Self.CheckDestroyed;

    Publish(Self.handle, topic, message, QOS, error);

    IF error /= 0 THEN
      RAISE MQTT.Error WITH "Paho_MQTT_sync.Publish() failed, " &
        strerror(error);
    END IF;
  END Publish;

  -- Subscribe to messages from the server

  PROCEDURE Subscribe
   (Self      : Server_Class;
    topic     : String;
    QOS       : Integer := Default_QOS) IS

    error : Integer;

  BEGIN
    Self.CheckDestroyed;

    Subscribe(Self.handle, topic, QOS, error);

    IF error /= 0 THEN
      RAISE MQTT.Error WITH "Paho_MQTT_sync.Subscribe() failed, " &
        strerror(error);
    END IF;
  END Subscribe;

  -- Unsubscribe to messages from the server

  PROCEDURE Unsubscribe
   (Self      : IN OUT Server_Class;
    topic     : String) IS

    error : Integer;

  BEGIN
    Self.CheckDestroyed;

    Unsubscribe(Self.handle, topic, error);

    IF error /= 0 THEN
      RAISE MQTT.Error WITH "Paho_MQTT_sync.Unsubscribe() failed, " &
        strerror(error);
    END IF;
  END Unsubscribe;

  -- Check whether an MQTT server object instance has been destroyed

  PROCEDURE CheckDestroyed(Self : Server_Class) IS

  BEGIN
    IF Self = Destroyed THEN
      RAISE Error WITH "This instance has been destroyed.";
    END IF;
  END CheckDestroyed;

  -- Second level subcribed message callback

  PROCEDURE subcallback2
   (context   : System.Address;
    topic     : Interfaces.C.Strings.chars_ptr;
    payload   : Interfaces.C.Strings.chars_ptr) IS

    Self : Server_Class :=
     (IF context = System.Null_Address THEN
        Destroyed
      ELSE
        SCC.To_Pointer(context).ALL);

  BEGIN
    IF Self.callback3 /= Null THEN
      Self.callback3(Interfaces.C.Strings.Value(topic),
        Interfaces.C.Strings.Value(payload));
    ELSE
      Put_Line("DEBUG: Topic   => " & Interfaces.C.Strings.Value(topic));
      Put_Line("DEBUG: Payload => " & Interfaces.C.Strings.Value(payload));
    END IF;
  END subcallback2;

END MQTT.Paho;